Only 15 UDP packets / second with W5100S-EVB-Pico possible?

[FeuerSturm]

Hi @khoih-prog ,

first of all thanks a lot for your efforts with all of your projects!

Now my question:
I am using your WiFiNINA_Generic library in my project and with an Arduino Nano RP2040 Connect,
a "default" Pi Pico with Adafruit Airlift ESP32 breakout and a Pi Pico with a Pimoroni Pico Wireless Jetpack
I am achieving around 50 to 60 UDP packets.
Now I've bought and received a W5100S-EVB-Pico and was seriously disappointed when it just reached
constant 15 UDP packets per second with the same code that I just modded to use your Ethernet_Generic lib
instead of the WiFiNINA-Generic lib.

Any idea about what could cause this?

Please let me know if you need any further information!

Thanks in advance!

[khoih-prog]

Hi @FeuerSturm

Thanks for your encouraging words about the libraries.

constant 15 UDP packets per second with the same code that I just modded to use your Ethernet_Generic lib
instead of the WiFiNINA-Generic lib.

It's really impossible for anyone to duplicate and understand the issue without Minimal, Reproducible Example. I guess now only you can try and figure out and get more info if the performance is somehow related on

1. Network / router (Ethernet versus WiFi, etc.)
2. W5100S-EVB-Pico hardware (SPI bus, clock, etc.)
3. W5100S-EVB-Pico Connection / Network cable
4. This Ethernet_Generic library and W5100S driver
5. ArduinoCore-mbed mbed_rp2040 / arduino-pico core performance

You can try and isolate by using

1. RP2040 + W5500
2. ArduinoCore-mbed mbed_rp2040 core, then compare to arduino-pico core
3. Nano_RP2040_Connect + ArduinoCore-mbed mbed_rp2040 core, then compare to arduino-pico core

Sorry I can't help anything now, and waiting for your test results.

[FeuerSturm]

Hi @khoih-prog

Thanks for your reply, I was sure that I included my sketch, but it seems like GitHub doesn't allow *.ino files,
I must have missed the notification about that when trying to add it.

The W5100S-EVB-Pico is connected via brand new CAT6 SFTP cable to my 1gbit home network,
so I am pretty sure that's not the limiting factor.
I did not change any settings "by hand", just using the default settings of your library.
I am using arduino-pico core with TinyUSB as I need being able to set VID/PID/Manufacturer/Product and receive USB HID packets,
to be honest, I haven't tested the Arduino mbed_RP2040 yet to see if that works in conjunction with TinyUSB as well,
that will be my task for after work today.

I don't have any ethernet shields that I could test, all I have is the W5100S-EVB-Pico.

Why question was rather a general one instead of a "fix my code please!" one, thought it might be a hardware
limitation of that W5100S chip that it simply cannot send more packets per second.

I'll see if I can strip the code down to a minimum and will post that after work.

Thanks for your time!

[FeuerSturm]

@khoih-prog

I found the problem, it seems that using the hostname of the target device for sending the UDP packets slows sending them down massively.
I am only getting 15 to 20 UDP packets per second via the hostname, while I am getting litterally hundreds of packets per second when directly sending to the target device's IP address.

This is my absolutely minimal test sketch:
udp_test.txt

Could you please be so kind and investigate?

Thank you!

[khoih-prog]

It's good you spent some more time to investigate, but you still need to understand more about the network / DNS operation.

Try the following code and study then know what you've done wrong (I won't go into details and hope your research will help you better)

#include <Ethernet_Generic.h>

#define USE_HOSTNAME      true

EthernetUDP udp;

const unsigned int port = 21324;

#if !USE_HOSTNAME
  IPAddress myComputerIP = IPAddress(192, 168, 2, 30);
#else
  const char* myComputerName = "MyComputer";
  IPAddress myComputerIP;
#endif

const byte testPacket[] = { 0x04, 0x02, 0x00, 0x00, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF };

void setup()
{

  Serial.begin(115200);
  while (!Serial && millis() < 5000);

  delay(500);

#if USE_HOSTNAME
  Serial.print(F("\nStarting UDP_Test USE_HOSTNAME on "));
#else
  Serial.print(F("\nStarting UDP_Test USE_IP on "));
#endif

  Serial.println(BOARD_NAME);

  Ethernet.init(17);
  byte mac[] = { 0xBE, 0xEF, 0xBE, 0xEF, 0xBE, 0xEF };
  Ethernet.begin(mac);
  udp.begin(port);

#if USE_HOSTNAME
  DNSClient dns;

  dns.begin(Ethernet.dnsServerIP());
  dns.getHostByName(myComputerName, myComputerIP);
  Serial.print(F("myComputerIP = ")); Serial.println(myComputerIP);
#endif
}

bool toPrint = false;
uint32_t packetCount = 0;

#define PRINT_INTERVAL    10000L

void countPrint()
{
  if (!toPrint)
    toPrint = true;
  else
  {
    Serial.print(F("PacketCount = ")); Serial.print(packetCount);
    Serial.print(F(", packetCount per sec = ")); Serial.println(packetCount * 1000 / PRINT_INTERVAL);
  }

  packetCount = 0;
}

void print_result()
{
  static unsigned long print_timeout = PRINT_INTERVAL;

  // Print hearbeat every PRINT_INTERVAL (10) seconds.
  if ((millis() >= print_timeout))
  {
    countPrint();
    print_timeout = millis() + PRINT_INTERVAL;
  }
}

void loop()
{
  udp.beginPacket(myComputerIP, port);
  udp.write(testPacket, 64);
  udp.endPacket();

  packetCount++;

  print_result();
}

and you'll see the result is consistent, USE_HOSTNAME or not

---

mbed_rp2040 core => worse network performance

UDP_Test USE_IP on RaspberryPi Pico

Starting UDP_Test USE_IP on RaspberryPi Pico
PacketCount = 4145, packetCount per sec = 414
PacketCount = 4145, packetCount per sec = 414

Starting UDP_Test USE_HOSTNAME on RaspberryPi Pico
myComputerIP = 192.168.2.31
PacketCount = 4142, packetCount per sec = 414
PacketCount = 4142, packetCount per sec = 414
PacketCount = 4142, packetCount per sec = 414

arduino-pico core => much better network performance

UDP_Test USE_HOSTNAME on RASPBERRY_PI_PICO

Starting UDP_Test USE_HOSTNAME on RASPBERRY_PI_PICO
myComputerIP = 192.168.2.31
PacketCount = 12594, packetCount per sec = 1259
PacketCount = 12594, packetCount per sec = 1259
PacketCount = 12594, packetCount per sec = 1259

Starting UDP_Test USE_IP on RASPBERRY_PI_PICO
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259
PacketCount = 12591, packetCount per sec = 1259

[FeuerSturm]

Yes, @khoih-prog , I think I see what I did wrong:
I triggered a new dns lookup for the provided hostname for each and every packet, several times a second, no wonder that slows it down to a minimum.
I guess I should fix that for the wifi version as well (even though that's sending packets fast enough for some reason).

Thanks a lot for your help! :D

[FeuerSturm]

Oh, by the way, would it be possible to get the ability to "setHostname" like we can do for Wifi in the future?
I've seen that "Ethernet3" has that feature, so it should be possible, correct?

[khoih-prog]

That's good idea. I'll have a look and implement. But also need your help to test then.

[khoih-prog]

HI @FeuerSturm

Please check the example SetDHCPHostName

---

Releases v2.3.1

1. Add setHostname() and related DHCP functions. Check Only 15 UDP packets / second with W5100S-EVB-Pico possible? #6
2. Add example SetDHCPHostName to demo the new feature
3. Update Packages' Patches

[FeuerSturm]

Hey @khoih-prog ,

setHostname works perfect, thanks a lot for implementing it so fast!