On demand indexing

apps/els_lsp/src/els_buffer_server.erl

@@ -0,0 +1,114 @@
+%%%=============================================================================
+%%% @doc Buffer edits to an open buffer to avoid re-indexing too often.
+%%% @end
+%%%=============================================================================
+-module(els_buffer_server).
+
+%%==============================================================================
+%% API
+%%==============================================================================
+-export([ new/2
+ , stop/1
+ , apply_edits/2
+ , flush/1
+ ]).
+
+-export([ start_link/2 ]).
+
+%%==============================================================================
+%% Callbacks for the gen_server behaviour
+%%==============================================================================
+-behaviour(gen_server).
+-export([ init/1
+ , handle_call/3
+ , handle_cast/2
+ , handle_info/2
+ ]).
+
+%%==============================================================================
+%% Macro Definitions
+%%==============================================================================
+-define(FLUSH_DELAY, 200). %% ms
+
+%%==============================================================================
+%% Type Definitions
+%%==============================================================================
+-type text() :: binary().
+-type state() :: #{ uri := uri()
+ , text := text()
+ , ref := undefined | reference()
+ }.
+-type buffer() :: pid().
+
+%%==============================================================================
+%% Includes
+%%==============================================================================
+-include_lib("kernel/include/logger.hrl").
+-include("els_lsp.hrl").
+
+%%==============================================================================
+%% API
+%%==============================================================================
+-spec new(uri(), text()) -> {ok, pid()}.
+new(Uri, Text) ->
+ supervisor:start_child(els_buffer_sup, [Uri, Text]).
+
+-spec stop(buffer()) -> ok.
+stop(Buffer) ->
+ supervisor:terminate_child(els_buffer_sup, Buffer).
+
+-spec apply_edits(buffer(), [els_text:edit()]) -> ok.
+apply_edits(Buffer, Edits) ->
+ gen_server:cast(Buffer, {apply_edits, Edits}).
+
+-spec flush(buffer()) -> ok.
+flush(Buffer) ->
+ gen_server:call(Buffer, {flush}).
+
+-spec start_link(uri(), text()) -> {ok, buffer()}.
+start_link(Uri, Text) ->
+ gen_server:start_link(?MODULE, {Uri, Text}, []).
+
+%%==============================================================================
+%% Callbacks for the gen_server behaviour
+%%==============================================================================
+-spec init({uri(), text()}) -> {ok, state()}.
+init({Uri, Text}) ->
+ do_flush(Uri, Text),
+ {ok, #{ uri => Uri, text => Text, ref => undefined }}.
+
+-spec handle_call(any(), {pid(), any()}, state()) -> {reply, any(), state()}.
+handle_call({flush}, _From, #{uri := Uri, text := Text} = State) ->
+ ?LOG_DEBUG("[~p] Flushing request [uri=~p]", [?MODULE, Uri]),
+ do_flush(Uri, Text),
+ {reply, ok, State};
+handle_call(Request, _From, State) ->
+ {reply, {not_implemented, Request}, State}.
+
+-spec handle_cast(any(), state()) -> {noreply, state()}.
+handle_cast({apply_edits, Edits}, #{uri := Uri} = State) ->
+ ?LOG_DEBUG("[~p] Applying edits [uri=~p]", [?MODULE, Uri]),
+ #{text := Text0, ref := Ref0} = State,
+ case Ref0 of
+ undefined -> ok;
+ _ -> erlang:cancel_timer(Ref0)
+ end,
+ Text = els_text:apply_edits(Text0, Edits),
+ Ref = erlang:send_after(?FLUSH_DELAY, self(), flush),
+ {noreply, State#{text => Text, ref => Ref}}.
+
+-spec handle_info(any(), state()) -> {noreply, state()}.
+handle_info(flush, #{uri := Uri, text := Text} = State) ->
+ ?LOG_DEBUG("[~p] Scheduled flushing [uri=~p]", [?MODULE, Uri]),
+ do_flush(Uri, Text),
+ {noreply, State};
+handle_info(_Request, State) ->
+ {noreply, State}.
+
+%%==============================================================================
+%% Internal Functions
+%%==============================================================================
+-spec do_flush(uri(), text()) -> ok.
+do_flush(Uri, Text) ->
+ {ok, Document} = els_utils:lookup_document(Uri),
+ els_indexing:deep_index(Document#{text => Text, buffer => self()}).

apps/els_lsp/src/els_buffer_sup.erl

@@ -0,0 +1,47 @@
+%%==============================================================================
+%% Supervisor for Buffers
+%%==============================================================================
+-module(els_buffer_sup).
+
+%%==============================================================================
+%% Behaviours
+%%==============================================================================
+-behaviour(supervisor).
+
+%%==============================================================================
+%% Exports
+%%==============================================================================
+
+%% API
+-export([ start_link/0 ]).
+
+%% Supervisor Callbacks
+-export([ init/1 ]).
+
+%%==============================================================================
+%% Defines
+%%==============================================================================
+-define(SERVER, ?MODULE).
+
+%%==============================================================================
+%% API
+%%==============================================================================
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+ supervisor:start_link({local, ?SERVER}, ?MODULE, []).
+
+%%==============================================================================
+%% Supervisor callbacks
+%%==============================================================================
+-spec init([]) -> {ok, {supervisor:sup_flags(), [supervisor:child_spec()]}}.
+init([]) ->
+ SupFlags = #{ strategy => simple_one_for_one
+ , intensity => 5
+ , period => 60
+ },
+ ChildSpecs = [#{ id => els_buffer_sup
+ , start => {els_buffer_server, start_link, []}
+ , restart => temporary
+ , shutdown => 5000
+ }],
+ {ok, {SupFlags, ChildSpecs}}.

apps/els_lsp/src/els_completion_provider.erl

@@ -44,8 +44,17 @@ handle_request({completion, Params}, State) ->
  }
  , <<"textDocument">> := #{<<"uri">> := Uri}
  } = Params,
- ok = els_index_buffer:flush(Uri),
- {ok, #{text := Text} = Document} = els_utils:lookup_document(Uri),
+ {ok, Document} = els_utils:lookup_document(Uri),
+ #{text := Text, buffer := Buffer} = Document,
+ %% Ensure there are no pending changes. This causes a heavy sync
+ %% point, since for a big module indexing could take a while. Maybe
+ %% just do a 'soft' flush and avoid indexing here?
+ case Buffer of
+ undefined ->
+ ok;
+ _ ->
+ ok = els_buffer_server:flush(Buffer)
+ end,
  Context = maps:get( <<"context">>
  , Params
  , #{ <<"triggerKind">> => ?COMPLETION_TRIGGER_KIND_INVOKED }

apps/els_lsp/src/els_dt_document.erl

@@ -45,6 +45,7 @@
 -type id() :: atom().
 -type kind() :: module | header | other.
 -type source() :: otp | app | dep.
+-type buffer() :: pid().
 -export_type([source/0]).
 
 %%==============================================================================
@@ -58,6 +59,7 @@
  , md5 :: binary() | '_'
  , pois :: [poi()] | '_' | ondemand
  , source :: source() | '$2'
+ , buffer :: buffer() | '_' | undefined
  }).
 -type els_dt_document() :: #els_dt_document{}.
 
@@ -68,6 +70,7 @@
  , md5 => binary()
  , pois => [poi()] | ondemand
  , source => source()
+ , buffer => buffer() | undefined
  }.
 -export_type([ id/0
  , item/0
@@ -97,6 +100,7 @@ from_item(#{ uri := Uri
  , md5 := MD5
  , pois := POIs
  , source := Source
+ , buffer := Buffer
  }) ->
  #els_dt_document{ uri = Uri
  , id = Id
@@ -105,6 +109,7 @@ from_item(#{ uri := Uri
  , md5 = MD5
  , pois = POIs
  , source = Source
+ , buffer = Buffer
  }.
 
 -spec to_item(els_dt_document()) -> item().
@@ -115,6 +120,7 @@ to_item(#els_dt_document{ uri = Uri
  , md5 = MD5
  , pois = POIs
  , source = Source
+ , buffer = Buffer
  }) ->
  #{ uri => Uri
  , id => Id
@@ -123,6 +129,7 @@ to_item(#els_dt_document{ uri = Uri
  , md5 => MD5
  , pois => POIs
  , source => Source
+ , buffer => Buffer
  }.
 
 -spec insert(item()) -> ok | {error, any()}.
@@ -162,6 +169,7 @@ new(Uri, Text, Id, Kind, Source) ->
  , md5 => MD5
  , pois => ondemand
  , source => Source
+ , buffer => undefined
  }.
 
 %% @doc Returns the list of POIs for the current document
@@ -221,10 +229,12 @@ find_candidates(Pattern) ->
  %% when Source =/= otp -> {Uri, Text} end).
  MS = [{#els_dt_document{ uri = '$1'
  , source = '$2'
+ , buffer = '_'
  , kind = '_'
  , text = '$3'
  , md5 = '_'
- ,pois = '_'}
+ , pois = '_'
+ }
  , [{'=/=', '$2', otp}]
  , [{{'$1', '$3'}}]}],
  All = ets:select(name(), MS),

apps/els_lsp/src/els_dt_signatures.erl

@@ -74,8 +74,8 @@ insert(Map) when is_map(Map) ->
 
 -spec lookup(mfa()) -> {ok, [item()]}.
 lookup({M, _F, _A} = MFA) ->
- {ok, Uris} = els_utils:find_modules(M),
- [els_indexing:ensure_deeply_indexed(Uri) || Uri <- Uris],
+ %% By finding a module, we also ensure the module is deeply indexed.
+ {ok, _Uris} = els_utils:find_modules(M),
  {ok, Items} = els_db:lookup(name(), MFA),
  {ok, [to_item(Item) || Item <- Items]}.