Theme conversion methodology or instructions?

[ylluminate]

I'd like to use the Bira theme (or perhaps something similar) with Zim. Are there any direct paths to do this or discussions of how to go about converting themes that I'm missing?

[antoineco]

There might be modifications needed for themes that use functionalities specific to ohmyzsh, but an example can be found here: #472 (comment)

Use the --source parameter like zmodule ohmyzsh/ohmyzsh --root themes --source bira.zsh-theme.

[ericbn]

Hi @ylluminate.

The main conversion you'll need to do for an ohmyzsh theme to Zim is how git information is handled. Ohmyzsh configures that via the ZSH_THEME_GIT_PROMPT_* environment variables, and Zim uses zstyle to set up our git-info module. Also some other prompt information is handled differently, like how to display the Python venv information.

To start understanding how themes are written, so you can rewrite one, check this comment.

You can use the ohmyzsh prompt directly as @antoineco mentioned. Add this to your .zimrc:

zmodule ohmyzsh/ohmyzsh --source lib/git.zsh
zmodule ohmyzsh/ohmyzsh --source lib/prompt_info_functions.zsh
zmodule ohmyzsh/ohmyzsh --source themes/bira.zsh-theme

EDIT: You'll also need to add:

autoload -Uz colors && colors

to the beginning of your .zshrc file.

You can see ohmyzsh is not exactly modular. This was one of the aspects that @sorin-ionescu improved in Prezto and that we also took as inspiration for Zim.

[ericbn]

Here's the bira theme rewritten for Zim:

# vim:et sts=2 sw=2 ft=zsh

typeset -g VIRTUAL_ENV_DISABLE_PROMPT=1

setopt nopromptbang prompt{cr,percent,sp,subst}

# Depends on git-info module to show git information
typeset -gA git_info
if (( ${+functions[git-info]} )); then
  zstyle ':zim:git-info:branch' format '%b'
  zstyle ':zim:git-info:commit' format '%c'
  zstyle ':zim:git-info:dirty' format '%F{red}●%F{yellow}'
  zstyle ':zim:git-info:keys' format \
      'prompt' ' %F{yellow}‹%b%c%D›'
  add-zsh-hook precmd git-info
fi

PS1='╭─%B%(!.%F{red]}.%F{green})%n@%m %F{blue}%~${(e)git_info[prompt]}${VIRTUAL_ENV:+" %F{green}‹${VIRTUAL_ENV:t}›"}%f%b
╰─%B%(!.#.$)%b '
RPS1='%B%(?..%F{red}%? ↵%f)%b'

What was removed: showing rvm and hg (mercurial) information.

I might just upload this as a new module in Zim... Need to add documentation and the LICENSE.

[ericbn]

Finally got to upload this as a new module: https://github.com/zimfw/bira