Wakeup by USART (SerialDeepSleep example from STM32LowPower)

[tshcherban]

Hi
I've looked at the SerialDeepSleep example from the STM32LowPower library and found out that USART is losing an incoming data. MCU is woken up from sleep/deepSleep modes but Serial reads garbage.
Is that normal behavior?
I'm using Nucleo-L053R8. Have also tried manually override SystemClock_Config to use HSI but that didn't change the behavior.
UPD.
On a long lines it catches first, misses next 4, and the rest is ok at 38400 bauds.
Or catches first, misses next one, and the rest is ok if 9600 bauds.
UPD2.
can it be related to this?

Low-power sleep mode
This mode is achieved by entering Sleep mode with the internal voltage regulator in
low-power mode to minimize the regulator’s operating current. In Low-power sleep
mode, both the clock frequency and the number of enabled peripherals are limited; a
typical example would be to have a timer running at 32 kHz

@fpistm

[tshcherban]

Also found that a STM32LowPower::sleep does switching the system clock to a MSI (range 1, 131.072 KHz), that explains Serial scramble:

#if defined(PWR_LOWPOWERREGULATOR_ON) && \
    (defined(PWR_CSR_REGLPF) || defined(PWR_SR2_REGLPF))
  // When LowPower regulator sleep mode is used, it is necessary to decrease CPU Frequency
  if (regulator == PWR_LOWPOWERREGULATOR_ON) {
    SystemClock_Decrease();
  }
#endif

However I couldn't find that within datasheet or a reference manual. RM says that Vdd domain should be not affected

and HSI16 should be disabled only in stop/standby modes

[fpistm]

Well switch to MSI is to be as generic as possible and not specifically linked to UART.
So, this is normal you lost some byte while the wakeup occurs. Simply adapt to sent dummy frame to wake up the board then sent you data.

[tshcherban]

after using sleep() even once in the setup - Serial is broken, cant read reliably at all. I've tried different speeds, and it only changes error pattern, but no valid data can be read reliably.

[fpistm]

Is it a custom board ?

[tshcherban]

nope, that's a Nucleo-L053R8.

[fpistm]

OK.
I've tested, some data are effectively lost but this is due to the fact the MCU enter in deepsleep again before receiving all data.
Could you try this sketch updated, Only 1 bytes is lost due to the wakeup time.

#include "STM32LowPower.h"

// Declare it volatile since it's incremented inside an interrupt
volatile int wakeup_counter = 0;

void setup() {
  Serial.begin(9600);
  // initialize digital pin LED_BUILTIN as an output.
  pinMode(LED_BUILTIN, OUTPUT);
  // Configure low power
  LowPower.begin();
  // Enable UART in Low Power mode wakeup source
  LowPower.enableWakeupFrom(&Serial, SerialWakeup);
  Serial.println("Start deep sleep wakeup from Serial");
}

void loop() {
  digitalWrite(LED_BUILTIN, HIGH);
  delay(500);
  digitalWrite(LED_BUILTIN, LOW);
  delay(500);
  // Triggers an infinite deep sleep
  // (the device will be woken up only by the registered wakeup sources)
  // The power consumption of the chip will drop consistently
  if (!Serial.available()) {
    LowPower.deepSleep();
    Serial.print(wakeup_counter);
    Serial.println(" wake up");
  }
  // Empty Serial Rx
  while (Serial.available()) {
    char c = Serial.read();
    Serial.print(c);
  }
  Serial.println();
  Serial.flush();
}

void SerialWakeup() {
  // This function will be called once on device wakeup
  // You can do some little operations here (like changing variables
  // which will be used in the loop)
  // Remember to avoid calling delay() and long running functions
  // since this functions executes in interrupt context
  wakeup_counter++;
}