-
Notifications
You must be signed in to change notification settings - Fork 394
/
build.gradle
166 lines (143 loc) · 5.02 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
buildscript {
repositories {
mavenCentral()
maven { url "https://plugins.gradle.org/m2/" }
}
dependencies {
classpath 'org.github.ngbinh.scalastyle:gradle-scalastyle-plugin_2.11:1.0.1'
}
}
plugins {
id 'com.github.johnrengelman.shadow' version '2.0.4'
id 'com.commercehub.gradle.plugin.avro' version '0.8.0'
}
repositories {
jcenter()
mavenCentral()
}
apply plugin: 'application'
apply plugin: 'java'
apply plugin: 'scala'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'scalaStyle'
apply plugin: 'com.commercehub.gradle.plugin.avro'
apply from: 'gradle/tests.gradle'
apply from: 'gradle/spark.gradle'
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
// The main class for the application plugin and is currently unused. Setting a dummy one.
mainClassName = "com.salesforce.dummy.DummyMain"
ext {
scalaVersion = '2.11'
scalaVersionRevision = '12'
junitVersion = '4.11'
sparkVersion = '2.3.2'
scalatestVersion = '3.0.0'
transmogrifaiVersion ='0.5.0'
collectionsVersion = '3.2.2'
mainClassName = "com.salesforce.dummy.DummyMain"
}
//noinspection GroovyAssignabilityCheck
configurations {
scalaLibrary
scalaCompiler
}
//noinspection GroovyAssignabilityCheck
dependencies {
// Scala
zinc 'com.typesafe.zinc:zinc:0.3.15'
scalaLibrary "org.scala-lang:scala-library:$scalaVersion.$scalaVersionRevision"
scalaCompiler "org.scala-lang:scala-compiler:$scalaVersion.$scalaVersionRevision"
compile "org.scala-lang:scala-library:$scalaVersion.$scalaVersionRevision"
// Spark
compileOnly "org.apache.spark:spark-core_$scalaVersion:$sparkVersion"
testCompile "org.apache.spark:spark-core_$scalaVersion:$sparkVersion"
compileOnly "org.apache.spark:spark-mllib_$scalaVersion:$sparkVersion"
testCompile "org.apache.spark:spark-mllib_$scalaVersion:$sparkVersion"
compileOnly "org.apache.spark:spark-sql_$scalaVersion:$sparkVersion"
testCompile "org.apache.spark:spark-sql_$scalaVersion:$sparkVersion"
// TransmogrifAI
compile "com.salesforce.transmogrifai:transmogrifai-core_$scalaVersion:$transmogrifaiVersion"
// Pretrained models used in TransmogrifAI, e.g. OpenNLP POS/NER models etc. (optional)
// compile "com.salesforce.transmogrifai:transmogrifai-models_$scalaVersion:$transmogrifaiVersion"
// Test
testCompile "org.scalatest:scalatest_$scalaVersion:$scalatestVersion"
testCompile "junit:junit:${junitVersion}"
}
configurations.all {
resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
resolutionStrategy {
force "commons-collections:commons-collections:$collectionsVersion",
"org.scala-lang:scala-library:$scalaVersion.$scalaVersionRevision",
"org.scala-lang:scala-reflect:$scalaVersion.$scalaVersionRevision"
}
}
configurations.zinc {
resolutionStrategy {
force 'org.scala-lang:scala-library:2.10.6', 'org.scala-lang:scala-reflect:2.10.6'
}
}
tasks.withType(ScalaCompile) {
configure(scalaCompileOptions.forkOptions) {
memoryMaximumSize = '1g'
jvmArgs = ['-XX:MaxMetaspaceSize=256m']
}
}
compileScala { scalaCompileOptions.additionalParameters = ["-optimize"] }
compileTestScala { scalaCompileOptions.additionalParameters = ["-Yrangepos"] }
[compileJava, compileTestJava]*.options.collect { options -> options.encoding = 'UTF-8' }
jar {
manifest.attributes "Main-Class": "$mainClassName"
baseName = "${rootProject.name}"
}
shadowJar {
zip64 = true
exclude 'META-INF/**'
baseName = jar.baseName
}
scalaStyle {
configLocation = "${rootProject.projectDir}/gradle/scalastyle-config.xml"
includeTestSourceDirectory = true
source = "src/main/scala"
testSource = "src/test/scala"
}
compileScala.dependsOn(scalaStyle)
avro {
createSetters = true
fieldVisibility = "PUBLIC_DEPRECATED"
outputCharacterEncoding = "UTF-8"
stringType = "String"
}
sourceSets {
main {
java {
srcDir 'build/generated-main-avro-java'
}
}
}
wrapper {
gradleVersion = '4.10.2'
distributionType = Wrapper.DistributionType.BIN
distributionSha256Sum = 'b49c6da1b2cb67a0caf6c7480630b51c70a11ca2016ff2f555eaeda863143a29'
}
task runMain(type: JavaExec) {
description 'run a main class, i.e.: runMain -Dmain=MyMainClass -Dargs="arg1 arg2 arg3"'
main = System.getProperty("main")
classpath = sourceSets.main.runtimeClasspath
//noinspection GroovyAssignabilityCheck
systemProperties = System.getProperties()
args = System.getProperty("args", "") == "" ? new LinkedList<String>() : Arrays.asList(System.getProperty("args").split(" "))
}
task repl(type: JavaExec) {
description 'Start Scala repl.'
main = "scala.tools.nsc.MainGenericRunner"
classpath = sourceSets.main.runtimeClasspath + configurations.scalaCompiler
standardInput System.in
args '-usejavacp'
}
task classpath {
doLast {
description 'Print project classpath.'
println sourceSets.main.runtimeClasspath.asPath
}
}