-
Notifications
You must be signed in to change notification settings - Fork 0
/
parser_modules.f90
1942 lines (1690 loc) · 70.7 KB
/
parser_modules.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!------------------------------------------------------------------------------
! o MODULE DirectoryFileExist
! o MODULE mod_SyntaxFolder
! o MODULE EnvironmentAndSystem
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
MODULE DirectoryFileExist
!------------------------------------------------------------------------------
!
!++m* general_modules.f90/DirectoryFileExist
!
! NAME
! MODULE DirectoryFileExist
!
! PURPOSE
! Subroutines to check if file or directory exist.
!
! CONTAINS
! o SUBROUTINE DeleteFile
! o FUNCTION file_existsL
! o SUBROUTINE FileExistREAD ( filenameC)
! o SUBROUTINE DirectoryFileExistREAD (directoryC,filenameC)
! o FUNCTION directory_existsL
! o SUBROUTINE DirectoryExist (directoryC )
! o SUBROUTINE CreateDirectory
! o FUNCTION Position_of_last_slash
! o FUNCTION FileName_Without_Directory
! o FUNCTION FileName_Without_FileExtension
! o SUBROUTINE Add_Slash_To_DirectoryName
! o SUBROUTINE ReplaceSlashes
! o SUBROUTINE FileExistWRITE( filenameC)
! o SUBROUTINE ErrorMessage
! o FUNCTION SetGlobalDirectoryName
! o FUNCTION GetGlobalDirectoryName
! o FUNCTION GetTotalDirectoryName_C
! o FUNCTION GetDirectoryName_int_to_char000
! o SUBROUTINE CountLinesInFile
! o SUBROUTINE ReadFileAndStoreLines
! o SUBROUTINE CopyFile
!
! FILENAME
! common/general_modules.f90
!
! NOTES
! o Status="OLD" It is an error if the file does not exist before the OPEN is executed.
! o Status="NEW" It is an error if the file exists already before the OPEN is executed.
! o Status="REPLACE" - If file does not exist, it is created.
! - If file exists, it is deleted and created anew.
!
!##
!
!-----------------------------------------------------------------
IMPLICIT NONE
CONTAINS
!------------------------------------------------------------------------------
SUBROUTINE DeleteFile(filenameC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/DeleteFile
!
! NAME
! SUBROUTINE DeleteFile
!
! PURPOSE
! Deletes a file.
!
! USAGE
! CALL DeleteFile(filenameC)
!
! INPUT
! o filenameC
!
! OUTPUT
! none
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
USE system_specific_parser ,ONLY:DebugLevel
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: filenameC
INTEGER :: status
!--------------
! Delete file.
!--------------
OPEN (UNIT=10,FILE=filenameC,STATUS='OLD',IOSTAT=status)
IF (status == 0) THEN
IF (DebugLevel > 5) THEN
WRITE(my_output_unit,'(A,A)') " Delete File: ",TRIM(filenameC)
END IF
CLOSE(UNIT=10, STATUS='DELETE')
END IF
!------------------------------------------------------------------------------
END SUBROUTINE DeleteFile
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION file_existsL(filenameC) RESULT(FileExistsL)
!------------------------------------------------------------------------------
!
!++f* DirectoryFileExist/file_existsL
!
! NAME
! FUNCTION file_existsL
!
! PURPOSE
! Check if file exists.
! If yes, flag 'FileExistsL' is .TRUE.
! If no , flag 'FileExistsL' is .FALSE.
!
! USAGE
! file_existsL(filenameC)
!
! INPUT
! o filenameC
!
! OUTPUT
! o FileExistsL
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: filenameC
LOGICAL :: FileExistsL ! RESULT
LOGICAL :: it_existsL
!-----------------------------------------------------------
! The INQUIRE statement determines whether the file exists.
!-----------------------------------------------------------
INQUIRE (FILE = filenameC, EXIST = it_existsL)
IF (it_existsL) THEN
FileExistsL = .TRUE.
ELSE
FileExistsL = .FALSE.
! WRITE(my_output_unit,'(2A/)') " >> Cannot find file = ", TRIM(filenameC)
! IF (PRESENT(error)) THEN
! CALL ErrorMessage(error)
! END IF
END IF
!------------------------------------------------------------------------------
END FUNCTION file_existsL
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE FileExistREAD(filenameC,error,ErrorMessageC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/FileExistREAD
!
! NAME
! SUBROUTINE FileExistREAD
!
! PURPOSE
! Checks if file exists.
! If it does not exist, an error is printed.
!
! USAGE
! CALL FileExistREAD(filenameC,error,ErrorMessageC)
!
! INPUT
! o filenameC
! o error (optional)
! o ErrorMessageC (optional)
!
! OUTPUT
! none
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: filenameC
INTEGER ,INTENT(in),OPTIONAL :: error
CHARACTER(len=*),INTENT(in),OPTIONAL :: ErrorMessageC
IF ( .NOT. file_existsL(filenameC) ) THEN
WRITE(my_output_unit,'(A,A,A)') " Error FileExistREAD: File ",TRIM(filenameC)," does not exist."
WRITE(my_output_unit,'(A)') " Please check if either directory or filename is wrong."
WRITE(my_output_unit,'(A)') ' Note: Blanks are allowed in filename if the filename is between quotation marks'// &
' "<filename>".'
WRITE(my_output_unit,'(A)') " Blanks are allowed in filename if the filename is between apostrophes "// &
" '<filename>'."
IF ( PRESENT(ErrorMessageC) ) THEN
WRITE(my_output_unit,'(1x,A)') TRIM(ErrorMessageC)
END IF
IF ( PRESENT(error) ) THEN
CALL ErrorMessage(error)
END IF
STOP
END IF
!------------------------------------------------------------------------------
END SUBROUTINE FileExistREAD
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE DirectoryFileExistREAD(directoryC,filenameC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/DirectoryFileExistREAD
!
! NAME
! SUBROUTINE DirectoryFileExistREAD
!
! PURPOSE
! Checks if file 'filenameC' exists in directory 'directoryC'.
! If it does not exist, an error is printed.
!
! USAGE
! CALL DirectoryFileExistREAD(directoryC,filenameC)
!
! INPUT
! o directoryC
! o filenameC
!
! OUTPUT
! none
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
IMPLICIT NONE
CHARACTER(len=*), INTENT(in) :: directoryC
CHARACTER(len=*), INTENT(in) :: filenameC
CHARACTER(len=:),ALLOCATABLE :: filename2C
filename2C = TRIM(directoryC)//TRIM(filenameC)
IF ( .NOT. file_existsL(filename2C) ) THEN
WRITE(my_output_unit,'(A,A,A)') " Error DirectoryFileExistREAD: File ",TRIM(filenameC)," does"
WRITE(my_output_unit,'(A,A)') " not exist in directory: ",TRIM(directoryC)
WRITE(my_output_unit,'(A)') " Please check if either directory or filename is wrong."
WRITE(my_output_unit,'(A)') ' Note: Blanks are allowed in filename if the filename is between quotation marks'// &
' "<filename>".'
WRITE(my_output_unit,'(A)') " Blanks are allowed in filename if the filename is between apostrophes "// &
" '<filename>'."
STOP
END IF
!-----------------------------------------------------------------
END SUBROUTINE DirectoryFileExistREAD
!-----------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION directory_existsL(directoryC) RESULT(DirectoryExistsL)
!------------------------------------------------------------------------------
!
!++f* FUNCTION/directory_existsL
!
! NAME
! SUBROUTINE directory_existsL
!
! PURPOSE
! Checks if directory exists.
! If yes, flag 'DirectoryExistsL' is .TRUE.
! If no , flag 'DirectoryExistsL' is .FALSE.
!
! USAGE
! directory_existsL(directoryC, DirectoryExistsL)
!
! INPUT
! o directoryC
!
! OUTPUT
! o DirectoryExistsL
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
USE system_specific_parser ,ONLY:DebugLevel
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: directoryC
LOGICAL :: DirectoryExistsL ! RESULT
INTEGER :: ios
CHARACTER(len=:),ALLOCATABLE :: filenameC
LOGICAL :: NewRoutineL
INTEGER,PARAMETER :: DebugNumber = 123
IF ( DebugLevel == DebugNumber) THEN ! For testing
NewRoutineL = .TRUE. ! It seems that this is still not working with Intel Fortran compiler on Windows. (2020-01-20)
ELSE
NewRoutineL = .FALSE.
END IF
IF (NewRoutineL) THEN
!------------------------------------------------------------------------------
! On Windows and Linux/UNIX/OSX a directory contains a special file named ".".
!------------------------------------------------------------------------------
! INQUIRE( FILE = 'mydirectory/.' , EXIST = DirectoryExistsL )
INQUIRE( FILE = TRIM(directoryC)//'.', EXIST = DirectoryExistsL ) ! CurrentSystem%DirectorySeparatorCharC is already contained in 'directoryC'.
IF ( DebugLevel == DebugNumber ) THEN
WRITE(my_output_unit,*) "Check existence of directoryC = ",TRIM(directoryC)//'.'
WRITE(my_output_unit,*) "DirectoryExistsL = ", DirectoryExistsL
END IF
ELSE
!----------------------------------------------------------------
! Note: This file will be deleted at the end of this subroutine.
! CHECK: What happens if this directory is write protected?
!----------------------------------------------------------------
filenameC = TRIM(directoryC)//'temp_file'
OPEN(UNIT=8,FILE=filenameC,IOSTAT=ios,STATUS="REPLACE",ACTION="WRITE")
IF (ios /= 0) THEN
DirectoryExistsL = .FALSE.
ELSE
DirectoryExistsL = .TRUE.
END IF
!-----------------------------------------------------------
! Delete file 'test.dat' because it is not needed any more.
!-----------------------------------------------------------
CLOSE(UNIT=8,STATUS='DELETE')
END IF
IF (.NOT. DirectoryExistsL) THEN
WRITE(my_output_unit,'(A,A,A)') " The directory '",TRIM(directoryC),"' does not exist yet."
!ELSE
! IF (DebugLevel > 10000) THEN
! WRITE(my_output_unit,'(A,A,A)') " The directory '",TRIM(directoryC),"' exists already."
! END IF
END IF
!------------------------------------------------------------------------------
END FUNCTION directory_existsL
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE DirectoryExist(directoryC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/DirectoryExist
!
! NAME
! SUBROUTINE DirectoryExist
!
! PURPOSE
! Checks if directory exists.
! If not, directory is created, and it is checked if directory
! had been created successfully.
!
! USAGE
! CALL DirectoryExist(directoryC)
!
! INPUT
! o directoryC
!
! OUTPUT
! none
!
! NOTES
! CHECK: IF a slash or backslash is not present, how does this affect this subroutine?
! Shall the slash or backslash be added automatically in this case?
!
!##
!
!-----------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: directoryC
!------------------------------------
! Check if directory exists already.
!------------------------------------
IF ( directory_existsL(directoryC) ) THEN
!-------------------------------------------------------------------------
! If .TRUE., then directory exists. Everything is fine. So let's return.
!-------------------------------------------------------------------------
RETURN
ELSE
!-------------------------------------------------------------------------
! If .FALSE., then create directory.
!-------------------------------------------------------------------------
CALL CreateDirectory(directoryC)
!-------------------------------------------------------------------------
! Here, I guess the program should wait for some time until the creation
! of the directory has finished.
!-------------------------------------------------------------------------
!---------------------------------------------------
! Check if directory has been created successfully.
!---------------------------------------------------
IF ( directory_existsL(directoryC) ) THEN
!------------------------------------------------------------------------
! If .TRUE., then directory exists. Everything is fine. So let's return.
!------------------------------------------------------------------------
RETURN
ELSE
WRITE(my_output_unit,'(A)') " Error DirectoryExist: I was not successful in creating this directory: "
WRITE(my_output_unit,'(1x,A)') TRIM(directoryC)
WRITE(my_output_unit,'(A)') " Please create it manually and start the executable again."
STOP
END IF
END IF
!------------------------------------------------------------------------------
END SUBROUTINE DirectoryExist
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE CreateDirectory(directory_inC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/CreateDirectory
!
! NAME
! SUBROUTINE CreateDirectory
!
! PURPOSE
! Creates directory.
!
! USAGE
! CALL CreateDirectory(directory_inC)
!
! INPUT
! o directory_inC
!
! OUTPUT
! none
!
! NOTES
! Program can now create a directory like this:
! 'simulations/1D/test/strain/' (i.e. including subdirectories)
!
! The slashes are modified if necessary, e.g.
! 'current/'
! 'current\'
!
!##
!
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
USE system_specific_parser ,ONLY:DebugLevel
USE mod_CallSystem ,ONLY:Execute_CommandLine
USE system_specific_parser ,ONLY:Windows,Linux,CurrentSystem
USE SpecialCharacters ,ONLY:BackSlashC
USE CharacterManipulation ,ONLY:CharacterReplace
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: directory_inC ! Input
INTEGER :: last
CHARACTER(len=987) :: SystemCommandC
CHARACTER(len=987) :: directoryC
CHARACTER(len=987) :: directory_for_mkdirC
!CHARACTER(len=:),ALLOCATABLE :: SystemCommandC
!CHARACTER(len=:),ALLOCATABLE :: directoryC
!CHARACTER(len=:),ALLOCATABLE :: directory_for_mkdirC
CHARACTER(len=1) :: char
INTEGER :: directoryC_StringLength
directoryC = TRIM(directory_inC)
WRITE(my_output_unit,'(A,A,A)') " Trying to create: '",TRIM(directoryC),"'"
!---------------------------------------------------------------
! Get string length (i.e. number of characters of 'directoryC'.
!---------------------------------------------------------------
directoryC_StringLength = LEN_TRIM(directoryC)
!-------------------------------------------------------
! Find position of last character '/' or '\' in string.
!-------------------------------------------------------
last = Position_of_last_slash(directoryC)
IF (last == 0) THEN
WRITE(my_output_unit,*) "Warning CreateDirectory:"
WRITE(my_output_unit,*) "It seems that no slash '/' or backslash '",BackSlashC,"' was present in the directory name."
WRITE(my_output_unit,*) "directory_inC = ",TRIM(directory_inC)
END IF
!------------------------------------------------------------------------------------------------
! Replace in string 'stringC' the character 'CharacterBeforeC' with character 'CharacterAfterC'.
! CALL CharacterReplace (stringC, CharacterBeforeC, CharacterAfterC )
! CurrentSystem%DirectorySeparatorCharC = '/' or '\'
!------------------------------------------------------------------------------------------------
IF (CurrentSystem%DirectorySeparatorCharC == Windows%DirectorySeparatorCharC) THEN
!-------------------------------------------
! Replace in 'directoryC' all '/' with '\'.
!-------------------------------------------
CALL CharacterReplace (directoryC, Linux%DirectorySeparatorCharC , CurrentSystem%DirectorySeparatorCharC )
ELSE IF (CurrentSystem%DirectorySeparatorCharC == Linux%DirectorySeparatorCharC) THEN
!-------------------------------------------
! Replace in 'directoryC' all '\' with '/'.
!-------------------------------------------
CALL CharacterReplace (directoryC, Windows%DirectorySeparatorCharC , CurrentSystem%DirectorySeparatorCharC )
ELSE
WRITE(my_output_unit,*) "Error CreateDirectory: This should not happen."
STOP
END IF
!------------------------------------------------------
! Take string 'directoryC' without the last slash '/'.
! This is achieved by using 'last-1'.
! Create directory, e.g. 'mkdir directoryC'.
!------------------------------------------------------
IF (last /= 0) THEN
char = directoryC(last:last) ! 'last' must be larger than zero.
IF (char /= CurrentSystem%DirectorySeparatorCharC) THEN
WRITE(my_output_unit,'(A,A,A,A)') " Warning CreateDirectory:", char, "/=" ,CurrentSystem%DirectorySeparatorCharC
WRITE(my_output_unit,'(A,A,A)') " Last character of directory name should be equal to slash '/' or backslash '", &
BackSlashC,"'."
WRITE(my_output_unit,'(A,A)') " directory name = ",TRIM(directoryC)
WRITE(my_output_unit,'(A,A,A,I5)') " last character = ", char," at position ",last
END IF
IF (last /= directoryC_StringLength) THEN
WRITE(my_output_unit,'(A)') " Warning CreateDirectory:"
WRITE(my_output_unit,'(A,A,A)') " Last character of directory name should be equal to slash '/' or backslash '", &
BackSlashC,"'."
WRITE(my_output_unit,'(A,A,A)') " directory name = ",TRIM(directoryC) ," (directory that should be created)"
WRITE(my_output_unit,'(A,A,A)') " directory name = ", directoryC(1:last)," (directory that will be created)"
WRITE(my_output_unit,'(A,I5)') " string length of directory name = ",directoryC_StringLength
WRITE(my_output_unit,'(A,I5,A)') " But I only use the first ",last," characters."
END IF
END IF
directory_for_mkdirC = TRIM(directoryC(1:last-1))
CALL Add_Slash_To_DirectoryName(directory_for_mkdirC) ! String must not be an allocatable string! [ CHARACTER(len=:),ALLOCATABLE ]
! SystemCommandC = TRIM(CurrentSystem%MakeDirC)//' ' //TRIM(directory_for_mkdirC)
SystemCommandC = TRIM(CurrentSystem%MakeDirC)//' '//'"'//TRIM(directory_for_mkdirC)//'"' ! "my folder" is possible now, i.e. including blanks.
!---------------------------------------------------------------------------
! If the correct slash is contained in 'directoryC', then this should work. BUT IT DOES NOT WORK!
!---------------------------------------------------------------------------
! SystemCommandC = TRIM(CurrentSystem%MakeDirC)//' ' //TRIM(directoryC(1:last))
!---------------------------------------------------------------------
! Now call the system (e.g. cmd.exe on Windows) and create directory.
!---------------------------------------------------------------------
WRITE(my_output_unit,'(A)') " Execute command line: '"//TRIM(SystemCommandC)//"'"
CALL Execute_CommandLine(TRIM(SystemCommandC))
IF (DebugLeveL > 3) THEN
WRITE(my_output_unit,'(A)') " Execute command line: '"//TRIM(SystemCommandC)//"' finished."
END IF
!------------------------------------------------------------------------------
END SUBROUTINE CreateDirectory
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION Position_of_last_slash(stringC) RESULT (index_of_last)
!------------------------------------------------------------------------------
!
!++f* DirectoryFileExist/Position_of_last_slash
!
! NAME
! FUNCTION Position_of_last_slash
!
! PURPOSE
! Finds the position of the last slash or backslash.
!
! USAGE
! Position_of_last_slash(stringC)
!
! INPUT
! o stringC: string
!
! OUTPUT
! o index_of_last position of last slash '/' or '\'
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
USE SpecialCharacters ,ONLY:BackSlashC
USE system_specific_parser,ONLY:Windows,Linux
IMPLICIT NONE
CHARACTER(len=*) ,INTENT(in) :: stringC
INTEGER :: index_of_last ! RESULT
INTEGER :: index_of_slash
INTEGER :: index_of_backslash
LOGICAL :: backL
index_of_slash = 0
index_of_backslash = 0
!-----------------------------------------------------------
! If backL=.TRUE., INDEX returns the maximum value of I
! such that string(I : I + LEN (substring) - 1) = substring
! (or zero if there is no such value).
!-----------------------------------------------------------
backL = .TRUE.
!--------------------------------------------------------------------------------------
! Here, we check both slashes because the user could have specified either '/' or '\'.
!--------------------------------------------------------------------------------------
index_of_slash = INDEX(TRIM(stringC), Linux%DirectorySeparatorCharC,backL) ! Get position of '/'.
index_of_backslash = INDEX(TRIM(stringC),Windows%DirectorySeparatorCharC,backL) ! Get position of '\'.
!------------------------------------------------------------------------
! We assume that the slash that is present has the higher integer value.
! The other value should be zero.
!------------------------------------------------------------------------
index_of_last = MAX(index_of_slash,index_of_backslash)
! IF (index_of_last == 0) THEN
! WRITE(my_output_unit,*) "Warning Position_of_last_slash:"
! WRITE(my_output_unit,*) "It seems that no slash '/' or backslash '",BackSlashC,"' was present in the string."
! WRITE(my_output_unit,*) "stringC = ",TRIM(stringC)
! END IF
!------------------------------------------------------------------------------
END FUNCTION Position_of_last_slash
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION FileName_Without_Directory(FilenameC) RESULT (Filename_without_DirectoryC)
!------------------------------------------------------------------------------
!
!++f* DirectoryFileExist/FileName_Without_Directory
!
! NAME
! FUNCTION FileName_Without_Directory
!
! PURPOSE
! Returns the actual filename without the leading directory path.
!
! USAGE
! FileName_Without_Directory(FilenameC)
!
! INPUT
! o FilenameC: string
!
! OUTPUT
! o Filename_without_DirectoryC: string without 'directory/'
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
IMPLICIT NONE
CHARACTER(len=*) ,INTENT(in) :: FilenameC
CHARACTER(len=:),ALLOCATABLE :: Filename_without_DirectoryC ! RESULT
INTEGER :: last
!---------------------------------------------------------------
! 'input_filenameC' is a string that could include directories.
!---------------------------------------------------------------
!-------------------------------------------------------
! Find position of last character '/' or '\' in string.
!-------------------------------------------------------
last = Position_of_last_slash(FilenameC)
!-------------------------------------------------------------
! Get actual filename, i.e. filename without any directories.
!-------------------------------------------------------------
Filename_without_DirectoryC = FilenameC( last+1 : LEN_TRIM(TRIM(FilenameC)) )
!------------------------------------------------------------------------------
END FUNCTION FileName_Without_Directory
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION FileName_Without_FileExtension(FilenameC) RESULT (Filename_without_FileExtensionC)
!------------------------------------------------------------------------------
!
!++f* DirectoryFileExist/FileName_Without_FileExtension
!
! NAME
! FUNCTION FileName_Without_FileExtension
!
! PURPOSE
! Returns the filename without file extension such as '.dat' or '.in'.
!
! USAGE
! FileName_Without_FileExtension(FilenameC)
!
! INPUT
! o FilenameC: string
!
! OUTPUT
! o filename_without_FileExtensionC: string without '.*'
!
! NOTES
!
!##
!
!------------------------------------------------------------------------------
IMPLICIT NONE
CHARACTER(len=*) ,INTENT(in) :: FilenameC
CHARACTER(len=:),ALLOCATABLE :: Filename_without_FileExtensionC ! RESULT
INTEGER :: index_of_dot
LOGICAL :: backL
index_of_dot = 0
!-----------------------------------------------------------
! If backL=.TRUE., INDEX returns the maximum value of I
! such that string(I : I + LEN (substring) - 1) = substring
! (or zero if there is no such value).
!-----------------------------------------------------------
backL = .TRUE.
!----------------------------------
! Get index of last '.' in string.
!----------------------------------
index_of_dot = INDEX(TRIM(FilenameC),'.',backL) ! Get position of '.'.
Filename_without_FileExtensionC = FilenameC(1:index_of_dot-1)
! IF (index_of_dot == 0) THEN
! WRITE(my_output_unit,*) "Warning FileName_Without_FileExtension:"
! WRITE(my_output_unit,*) "It seems that no '.' was present in the string."
! WRITE(my_output_unit,*) "FilenameC = ",TRIM(FilenameC)
! END IF
!------------------------------------------------------------------------------
END FUNCTION FileName_Without_FileExtension
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE Add_Slash_To_DirectoryName(DirectoryNameC)
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/Add_Slash_To_DirectoryName
!
! NAME
! SUBROUTINE Add_Slash_To_DirectoryName
!
! PURPOSE
! Checks if the last letter of this directory name is a slash or backslash.
! If this is not the case, a slash or backslash is added.
!
! USAGE
! CALL Add_Slash_To_DirectoryName(DirectoryNameC)
!
! INPUT
! o DirectoryNameC
!
! OUTPUT
! none
!
! NOTES
! Example: Input: output/test
! Output: output/test/
! NOTE: The variable DirectoryNameC which is input to this routine must not be an allocatable string [ CHARACTER(len=:),ALLOCATABLE ]!!!
!
!##
!
!-----------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
USE system_specific_parser ,ONLY:CurrentSystem
USE SpecialCharacters ,ONLY:BackSlashC
IMPLICIT NONE
CHARACTER(len=*),INTENT(inout) :: DirectoryNameC
INTEGER :: directoryC_StringLength
INTEGER :: directoryC_StringVariableLength
INTEGER :: last
!-----------------------------------------------------------------------------------------
! Get string length (i.e. number of characters of 'directoryC' including trailing blanks.
!-----------------------------------------------------------------------------------------
directoryC_StringVariableLength = LEN(DirectoryNameC)
!-------------------------------------------------------------------------------------------------
! Get string length (i.e. number of characters of 'directoryC' without including trailing blanks.
!-------------------------------------------------------------------------------------------------
directoryC_StringLength = LEN_TRIM(DirectoryNameC)
IF (directoryC_StringLength > 0) THEN
!-----------------------------------------------------------------
! Here we check if at least one character is contained in string.
!-----------------------------------------------------------------
!---------------------------------
! Define index of last character.
!---------------------------------
last = directoryC_StringLength
!-----------------------------------------------------------------------------
! If the last character is not a slash or backslash, we add it to the string.
!-----------------------------------------------------------------------------
IF ( ( DirectoryNameC(last:last) /= BackSlashC ) .AND. & ! Check if last letter = '\'
( DirectoryNameC(last:last) /= '/' ) ) THEN ! Check if last letter = '/'
IF ( directoryC_StringVariableLength == &
directoryC_StringLength ) THEN
WRITE(my_output_unit,'(A,A)') " Warning Add_Slash_To_DirectoryName: Cannot add slash to directory = ", &
TRIM(DirectoryNameC)
END IF
DirectoryNameC = TRIM(DirectoryNameC)//CurrentSystem%DirectorySeparatorCharC ! This variable is not initialized yet.
END IF
END IF
!------------------------------------------------------------------------------
END SUBROUTINE Add_Slash_To_DirectoryName
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE ReplaceSlashes( DirectoryFilenameC )
!------------------------------------------------------------------------------
!
!++s* DirectoryFileExist/ReplaceSlashes
!
! NAME
! SUBROUTINE ReplaceSlashes
!
! PURPOSE
! Replace in string all backslashes and slashes with the specific one of the operating system.
!
! USAGE
! CALL ReplaceSlashes(DirectoryFilenameC)
!
! INPUT
! o DirectoryFilenameC (also output)
!
! OUTPUT
! o DirectoryFilenameC (also input)
!
! NOTES
!
!##
!
!-----------------------------------------------------------------
USE system_specific_parser,ONLY:CurrentSystem
USE SpecialCharacters ,ONLY:BackSlashC
USE CharacterManipulation ,ONLY:CharacterReplace
IMPLICIT NONE
CHARACTER(len=*),INTENT(inout) :: DirectoryFilenameC
CALL CharacterReplace( DirectoryFilenameC , '/' , CurrentSystem%DirectorySeparatorCharC )
CALL CharacterReplace( DirectoryFilenameC , BackSlashC, CurrentSystem%DirectorySeparatorCharC )
!------------------------------------------------------------------------------
END SUBROUTINE ReplaceSlashes
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
SUBROUTINE FileExistWRITE(filenameC)
!------------------------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
IMPLICIT NONE
CHARACTER(len=*),INTENT(in) :: filenameC ! Input
INTEGER :: ios ! Helper
OPEN(UNIT=8,FILE=filenameC,IOSTAT=ios,STATUS="REPLACE",ACTION="WRITE")
IF (ios /= 0) THEN
WRITE(my_output_unit,'(A)') " Error FileExistWRITE: Unable to open the file:"
WRITE(my_output_unit,'(A,A,A)') " '",TRIM(filenameC),"'"
WRITE(my_output_unit,'(A)') " Please check if directory exists."
STOP
END IF
!------------------------------------------------------------
! Delete file 'filenameC' because it is not needed any more.
!------------------------------------------------------------
CLOSE(UNIT=8,STATUS='DELETE')
!-----------------------------------------------------------------
END SUBROUTINE FileExistWRITE
!-----------------------------------------------------------------
!
!
!
!-----------------------------------------------------------------
SUBROUTINE ErrorMessage(error)
!-----------------------------------------------------------------
USE My_Input_and_Output_Units,ONLY:my_output_unit
IMPLICIT NONE
INTEGER,INTENT(in) :: error
SELECT CASE(error)
CASE(1)
WRITE(my_output_unit,'(A)') " Error in keyword '$simulation-flow-control':"
WRITE(my_output_unit,'(A)') " You chose 'strain-calculation = raw-strain-in',"
WRITE(my_output_unit,'(A)') " therefore a file containing the raw data must exist."
WRITE(my_output_unit,'(A)') " If the file exists, maybe you forgot to specify the"
WRITE(my_output_unit,'(A)') " directory to read in from: 'raw-directory-in = ...'"
CASE(2)
WRITE(my_output_unit,'(A)') " Error in keyword '$import-data-on-material-grid' or '$doping-function', "
WRITE(my_output_unit,'(A)') " or any other keyword that reads in an ASCII file."
WRITE(my_output_unit,'(A)') " A file containing data to be read in must exist."
CASE(4)
WRITE(my_output_unit,'(A)') " Error macro: A macro file must exist if you want to read in a macro from a file."
CASE DEFAULT
WRITE(my_output_unit,'(A)') "[No specific error message defined.]"
END SELECT
!------------------------------------------------------------------------------
END SUBROUTINE ErrorMessage
!------------------------------------------------------------------------------
!
!
!
!------------------------------------------------------------------------------
FUNCTION SetGlobalDirectoryName(directoryC,Create_inL) RESULT (GlobalDirectoryC)
!------------------------------------------------------------------------------
!
!++f* DirectoryFileExist/SetGlobalDirectoryName
!
! NAME
! FUNCTION SetGlobalDirectoryName
!