settings.gradle

gradle.ext.modules = []
gradle.ext.addonInfo = new StringBuilder(512)
gradle.ext.localProps = new Properties()
gradle.ext.enableGoogleServices = (System.getenv('NO_GS') == null)
        && file('fermata/google-services.json').isFile()
def localPropsFile = file('local.properties')

if (localPropsFile.isFile()) {
    gradle.ext.localProps.load(localPropsFile.newDataInputStream())
} else {
    gradle.ext.localProps.setProperty('storeFile', file('res/test.ks').absolutePath)
    gradle.ext.localProps.setProperty('keyAlias', 'test')
    gradle.ext.localProps.setProperty('keyPassword', 'fermata')
    gradle.ext.localProps.setProperty('storePassword', 'fermata')
}

rootProject.name = 'Fermata Music Player'
include ':fermata'
include ':utils'
project(':utils').projectDir = file('depends/utils')

file('modules').eachDir {
    def name = ':' + it.name
    if ((':gdrive' == name) && !gradle.ext.enableGoogleServices) return
    gradle.ext.modules.add(name)
    include name
    project(name).projectDir = it
}