-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
507 lines (414 loc) · 12.8 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
{
inputs = {
# Path types: https://nixos.org/manual/nix/stable/command-ref/new-cli/nix3-flake.html#types
nixpkgs-unstable.url = github:NixOS/nixpkgs/nixpkgs-unstable;
nixpkgs-master.url = github:NixOS/nixpkgs/master;
nixpkgs.url = github:NixOS/nixpkgs/nixos-24.05;
# Darwin settings
nix-darwin = {
url = github:LnL7/nix-darwin;
inputs.nixpkgs.follows = "nixpkgs";
};
# Library functions
flake-utils.url = "github:numtide/flake-utils";
nix-std.url = "github:chessai/nix-std";
# Available modules: https://github.com/NixOS/nixos-hardware/blob/master/flake.nix
nixos-hardware.url = "github:NixOS/nixos-hardware/master";
check_mk_agent = {
url = "github:BenediktSeidl/nixos-check_mk_agent-overlay";
inputs.nixpkgs.follows = "nixpkgs";
};
# Secrets management
sops-nix = {
url = github:Mic92/sops-nix;
inputs.nixpkgs.follows = "nixpkgs";
};
# Home manager
home-manager = {
# TODO: change back when babelfish commit is in the stable release:
# https://github.com/nix-community/home-manager/commit/53ccbe017079d5fba2b605cb9f9584629bebd03a
url = github:nix-community/home-manager/release-24.05;
inputs.nixpkgs.follows = "nixpkgs";
};
nix-on-droid = {
url = "github:nix-community/nix-on-droid/release-23.11";
inputs.nixpkgs.follows = "nixpkgs";
inputs.home-manager.follows = "home-manager";
};
# Docker-compose in Nix
arion = {
url = github:hercules-ci/arion;
inputs.nixpkgs.follows = "nixpkgs";
};
nur.url = github:nix-community/NUR;
nixos-generators = {
url = "github:nix-community/nixos-generators";
inputs.nixpkgs.follows = "nixpkgs";
};
# Disk partitioning
disko = {
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
mobile-nixos = {
url = github:NixOS/mobile-nixos;
flake = false;
};
# Theming
# A decent alternative (can generate color from picture): https://git.sr.ht/~misterio/nix-colors
base16.url = github:SenchoPens/base16.nix/v1.1.1;
# Main theme
# https://github.com/chriskempson/base16#scheme-repositories
base16-atelier = {
url = github:atelierbram/base16-atelier-schemes;
flake = false;
};
base16-unclaimed = {
url = github:chriskempson/base16-unclaimed-schemes;
flake = false;
};
# Theme templates
# https://github.com/chriskempson/base16#template-repositories
base16-shell = {
url = github:chriskempson/base16-shell;
flake = false;
};
base16-fish-shell = {
url = github:FabioAntunes/base16-fish-shell;
flake = false;
};
base16-alacritty = {
url = github:aarowill/base16-alacritty;
flake = false;
};
base16-mako = {
url = github:Eluminae/base16-mako;
flake = false;
};
base16-wofi = {
url = https://git.sr.ht/~knezi/base16-wofi/archive/v1.0.tar.gz;
flake = false;
};
base16-waybar = {
url = github:mnussbaum/base16-waybar;
flake = false;
};
base16-sway = {
url = github:rkubosz/base16-sway;
flake = false;
};
base16-gtk = {
url = github:tinted-theming/base16-gtk-flatcolor;
flake = false;
};
};
outputs = {
self,
nixpkgs,
...
} @ inputs: let
overlays = {
dlo9 = import ./pkgs inputs;
unstable = system: final: prev: {
unstable = import inputs.nixpkgs-unstable {
inherit system;
config.allowUnfree = prev.config.allowUnfree;
};
};
master = system: final: prev: {
master = import inputs.nixpkgs-master {
inherit system;
config.allowUnfree = prev.config.allowUnfree;
};
};
};
linuxModules = [
# System modules
./system
# Host modules
./hosts
# Nix User repo
inputs.nur.nixosModules.nur
# Docker-compose in Nix
inputs.arion.nixosModules.arion
# Nixpkgs overlays
({
config,
inputs,
...
}: {
nixpkgs = {
config.allowUnfree = true;
overlays = with overlays; [
dlo9
(unstable "x86_64-linux")
(master "x86_64-linux")
];
};
})
];
darwinModules = [
# System modules
./system
# Host modules
./hosts
# Nix User repo
inputs.nur.nixosModules.nur
# Nixpkgs overlays
({
config,
inputs,
...
}: {
nixpkgs = {
hostPlatform = "aarch64-darwin";
config.allowUnfree = true;
overlays = with overlays; [
inputs.nix-darwin.overlays.default
dlo9
(unstable "aarch64-darwin")
(master "aarch64-darwin")
];
};
})
];
androidModules = [
# System modules
./system/home-manager.nix
./system/options.nix
# ./system/secrets.nix
# Host modules
./hosts
# Nix User repo
inputs.nur.nixosModules.nur
({config, ...}: {
environment.motd = null;
home-manager = {
useUserPackages = false; # TODO
extraSpecialArgs = {
osConfig = config;
};
};
})
];
# Pass extra arguments to modules
specialArgs = {
inherit inputs;
isDarwin = false;
isLinux = true;
isAndroid = false;
};
in rec {
# https://daiderd.com/nix-darwin/manual/index.html
darwinConfigurations = with inputs.nix-darwin.lib; rec {
mallow = darwinSystem {
specialArgs = {
inherit inputs;
isDarwin = true;
isLinux = false;
isAndroid = false;
hostname = "mallow";
};
system = "aarch64-darwin";
modules = darwinModules;
};
YX6MTFK902 = mallow;
};
nixOnDroidConfigurations = with inputs.nix-on-droid.lib; rec {
pixie = nixOnDroidConfiguration {
extraSpecialArgs = {
inherit inputs;
isDarwin = false;
isLinux = false;
isAndroid = true;
hostname = "pixie";
};
home-manager-path = inputs.home-manager.outPath;
system = "aarch64-linux";
modules = androidModules;
pkgs = import nixpkgs {
system = "aarch64-linux";
config.allowUnfree = true;
overlays = with overlays; [
inputs.nix-on-droid.overlays.default
dlo9
(unstable "aarch64-linux")
(master "aarch64-linux")
];
};
};
};
nixosConfigurations = with nixpkgs.lib; rec {
bee = nixosSystem {
specialArgs = specialArgs // {hostname = "bee";};
system = "x86_64-linux";
modules = linuxModules;
};
cuttlefish = nixosSystem {
specialArgs = specialArgs // {hostname = "cuttlefish";};
system = "x86_64-linux";
modules = linuxModules;
};
nib = nixosSystem {
specialArgs = specialArgs // {hostname = "nib";};
system = "x86_64-linux";
modules = linuxModules;
};
pavil = nixosSystem {
specialArgs = specialArgs // {hostname = "pavil";};
system = "x86_64-linux";
modules = linuxModules;
};
# https://mobile.nixos.org/devices/motorola-potter.html
# - Test with: nix eval "/etc/nixos#nixosConfigurations.moto.config.system.build.toplevel.drvPath"
# - Build with: nixos-rebuild build --flake path:https:///etc/nixos#moto
moto = nixosSystem {
specialArgs = specialArgs // {hostname = "moto";};
system = "aarch64-linux";
modules =
linuxModules
++ [
(import "${inputs.mobile-nixos}/lib/configuration.nix" {device = "motorola-potter";})
];
};
# Build with: `nix build 'path:.#nixosConfigurations.moto-image'`
# Impure needed to access host paths without putting in the nix store
moto-image = moto.config.mobile.outputs.android.android-fastboot-images;
rpi3 = nixosSystem {
specialArgs = specialArgs // {hostname = "rpi3";};
system = "aarch64-linux";
modules =
linuxModules
++ [
"${nixpkgs}/nixos/modules/installer/sd-card/sd-image-aarch64.nix"
];
};
# Build with: `nix build --impure 'path:.#nixosConfigurations.rpi3-image'`
# Impure needed to access host paths without putting in the nix store
rpi3-image = rpi3.config.system.build.sdImage;
drywell = nixosSystem {
specialArgs = specialArgs // {hostname = "drywell";};
system = "x86_64-linux";
modules = linuxModules;
};
installer-test = nixosSystem {
specialArgs = specialArgs // {hostname = "installer-test";};
system = "x86_64-linux";
modules = linuxModules;
};
};
# packages.x86_64-linux = {
# vmware = inputs.nixos-generators.nixosGenerate {
# system = "x86_64-linux";
# modules = [ ];
# format = "iso";
# };
# };
inherit overlays;
packages = let
change-to-flake-root = ''
# Change to flake root
while [ ! -f "flake.nix" ] && [ "$PWD" != "/" ]; do
cd ..
done
'';
in
inputs.flake-utils.lib.eachDefaultSystemMap (
system: let
pkgs = nixpkgs.legacyPackages.${system};
setVars = ''
if command -v nixos-rebuild >/dev/null; then
OS=linux
elif command -v darwin-rebuild >/dev/null; then
OS=darwin
elif command -v nix-on-droid >/dev/null; then
OS=android
fi
if [ -z "$HOSTNAME" ]; then
HOSTNAME="$(hostname)"
fi
'';
in rec {
default = {
type = "app";
program = "${packages.${system}.build}/bin/build";
};
generate-hardware = pkgs.writeShellApplication {
name = "generate-hardware";
# TODO: not yet supported
# runtimeEnv = {
# SYSTEM = system;
# };
text = ''
${setVars}
${change-to-flake-root}
if [[ "$OS" == "linux" ]]; then
echo "Generating hardware config"
config="hosts/$HOSTNAME/hardware/generated.nix"
mkdir -p "$(dirname "$config")"
# Ask for sudo now, so that the file isn't truncated
# if sudo fails
sudo -v
# Must use `sudo` so that all mounts are visible
sudo nixos-generate-config --show-hardware-config | \
scripts/maintenance/process-hardware-config.awk > "$config"
echo "Formatting hardware config"
nix fmt -- -q "$config"
fi
'';
};
build = pkgs.writeShellApplication {
name = "build";
# TODO: not yet supported
# runtimeEnv = {
# SYSTEM = system;
# };
text = ''
${setVars}
# If no options were provided, then default to switch
if [[ "''${#@}" == 0 ]]; then
set -- switch
fi
${change-to-flake-root}
# Format
echo "Formatting config"
nix fmt -- -q .
${generate-hardware}/bin/generate-hardware
if [[ "$OS" == "linux" ]]; then
sudo nixos-rebuild "$@" --option fallback true --show-trace
elif [[ "$OS" == "darwin" ]]; then
# Copy cert file already on the machine
certSource="/etc/ssl/afscerts/ca-certificates.crt"
if [ -f "$certSource" ]; then
cp "$certSource" "hosts/mallow/ca-certificates.crt"
fi
# Rebuild
darwin-rebuild --flake ".#$HOSTNAME" "$@" --option fallback true --show-trace
elif [[ "$OS" == "android" ]]; then
nix-on-droid --flake ".#$HOSTNAME" "$@" --option fallback true --show-trace
else
echo "Unknown os: $OS"
exit 1
fi
'';
};
}
);
apps = inputs.flake-utils.lib.eachDefaultSystemMap (
system: {
# nix run ".#default" build
# nix run ".#default" switch
default = {
type = "app";
program = "${packages.${system}.build}/bin/build";
};
# nix run ".#generate-hardware"
generate-hardware = {
type = "app";
program = "${packages.${system}.generate-hardware}/bin/generate-hardware";
};
}
);
formatter = inputs.flake-utils.lib.eachDefaultSystemMap (system: nixpkgs.legacyPackages.${system}.alejandra);
};
}